tbl={
{0,0},
{Pi/6,1/2},
{Pi/4,1/Sqrt[2]},
{Pi/3,Sqrt[3]/2},
{Pi/2,1}
}(* wartości funkcji Sinus w pierwszej ćwiartce, oczywiście z pamięci *)

w=InterpolatingPolynomial[tbl,x]//Simplify//HornerForm//N
(* najszybszy sposób znalezienia wielomianu przechodzącego przez zadane punkty, dla prostoty skonwertowałem go do postaci Hornera ze współczynnikami danymi numerycznie *)

Table[w/.x->tbl[[ii,1]],{ii,1,5}]
(*
sprawdzenie czy wielomian faktycznie przechodzi przez podane punkty
*)

(* najprostszym sposobem zdefiniowania funkcji jest skopiowanie uzyskanego wcześniej wielomianu poprzez 
Ctrl+C Ctrl+V *)
sin[x_]:=x (0.9956261842752614`+x (0.021373007528865173`+(-0.20434069602165295`+0.02879711246041694` x) x));

sin[0]

sin[Pi/2]

Plot[{Sin[x],sin[x]},{x,0,Pi/2}](* wizualnie funkcje się nie różnią *)

Plot[Sin[x]-sin[x],{x,0,Pi/2}]
(* odjecie funkcji pokazuje błąd absolutny, tj. róznicę wartości funkcji *)

Plot[sin[x]/Sin[x]-1,{x,0,Pi/2},PlotRange->All]
(* podzielenie fukcji i odjęcie liczby jeden pokazuje błąd względny tj. ,,procentowy'' *)

(* sposób zdefiniowania funkcji bez kopiowania jej zawartości (ang. body) *)
sin2=Function[{x},Evaluate[w]]

sin2[Pi/4]