Clear[r0,ω,r,ϕ]

r=r0/Cos[ϕ] (* Położenie w układzie biegunowym *)

(* Odkomentuj linijkę poniżej aby dostać rozwiązanie dla grupy 2 *)

(* r=r0/(1+Cos[ϕ] )*)

Block[{r0=1},PolarPlot[r,{ϕ,-4/5Pi,4/5Pi}]](* Tor ruchu w układzie biegunowym, ang. polar coordinates *)

ϕ=ω t(* Zależność kąta ϕ w układzie biegunowym od czasu t *)

ex={1,0} (* wersor (wektor jednostkowy) w kierunu osi OX, w tzw.  układzie kartezjańskim *)

ey=Cross[ex] (* wersor w kieunku osi Oy, prostopadły do ex *)

er={Cos[ω t],Sin[ω t]} (* mniej oczywisty wersor w kierunku radialnym... *)

eϕ=Cross[er] (* ... i wersor w kierunku transwersalnym *)

R=r er (* wsp. kartezjańskie wektora położenia *)

V=D[R,t] (* wektor prędkości to pochodna wektora położenia *)

{D[R,t].ex,D[R,t].ey} (* składowe kartezjańskie, jako rzuty na wersory ex,ey - wynik oczywisty, tylko dla ilustracji metody *)

{V.er,V.eϕ}(* składowe w ukł. biegunowym (radialna i transwersalna) można oblicyć jako rzuty wektora V na wersory er,eϕ*)

{D[r,t],r D[ϕ,t]} (* jak wyżej, ale wg. wyprowadzonych na ćw. wzorów *)

%-%%//Simplify (* wynik identyczny *)

a=D[V,t] //Simplify(* przyspieszenie to pochodna prędkości *)

{a.er,a.eϕ}//Simplify

{D[r,t,t]-r D[ϕ,t]^2,r D[ϕ,t,t]+2 D[r,t]D[ϕ,t]}//Simplify

%-%%//Simplify

r0=1

ω=1

Manipulate[
Show[
ParametricPlot[R,{t,-1.5,T}],ListPlot[{R/.t->T},BaseStyle->PointSize->Large]
,PlotRange->4{{-1,1},{-1,1}},
AxesOrigin->{0,0},AspectRatio->1,
Epilog->{
{Red,Arrow[{R,R+ex}/.t->T]},
{Text["(Subscript[e, x])",R+ex/.t->T,{1,1}]},
{Blue,Arrow[{R,R+ey}/.t->T]},
{Text["(Subscript[e, y])",R+ey/.t->T,{1,1}]},
Arrow[{R,R+er}/.t->T],
{Text["(Subscript[e, r])",R+er/.t->T,{1,0}]},
Arrow[{R,R+eϕ}/.t->T],
{Text["(Subscript[e, ϕ])",R+eϕ/.t->T,{1,1}]},{Dotted,Line[{{0,0},R}/.t->T]}}
],{{T,1},-Pi/2,Pi/2}]