Definiujemy funkcję podcałkową:

fb1 = (x - 1)/Log[Abs[x]]

Definiujemy przedział całkowania:

p = {x, 0, 1}

fb1C  =  Integrate[fb1, p]

Funkcja Plot wywołana podobnie da komunikat o błędzie:

Plot[fb1, p]

Dzieje się tak gdyż Plot sprawdza swoje argumenty PRZED wywołaniem, a "p" nie jest przedziałem. Dlatego poprawne wywołanie to Plot[fb1,{x,0,1}] lub:

Plot[fb1, Evaluate[p]]

Jak widać funkcja jest ciągła i ,,ładna''. Dla takich funkcji całkowanie numeryczne nigdy nie zawodzi, więc możemy sprawdzić wynik numerycznie:

NIntegrate[fb1, Evaluate[p]] - N[fb1C]

Różnica jest znikomo mała (na poziomie dokładności numerycznej) więc wynik analityczny i numeryczny są poprawne.

fb2C  =  
      Integrate[
        1/(1 + Sin[ϕ]^2), {ϕ, -π/2, π/
            2}]

fb3 = (1 + Tan[ϕ]^2)^(3/2)

fb3C  =   Integrate[fb3, {ϕ, -π/4, π/4}]

To wygląda podejrzanie....sprawdzamy:

Plot[fb3, {ϕ, -π/4, π/4}]

NIntegrate[fb3, {ϕ, -π/4, π/4}] - 
      N[Integrate[fb3, {ϕ, -π/4, π/4}]]

Zwracam uwagę na różnicę pomiędzy NIntegrate[] a N[Integrate]. W pierwszym wypadku całka jest liczona od razu numerycznie, a w drugim analitycznie a następnie wynik jest przedstawiany w postaci numerycznej. Jak widać obliczanie całki numerycznie jest równie dokładne jak obliczanie wartości funcji Log czy Sin z dokładnością
16 miejsc po przecinku. Dokładność mozna zwiększać (za cenę znacznego spowolnienia obliczeń) do  wartości znacznie przekraczających precyzję procesora:

N[Integrate[fb3, {ϕ, -π/4, π/4}], 200]

NIntegrate[fb3, {ϕ, -π/4, π/4}, 
      PrecisionGoal -> 200, WorkingPrecision -> 300]

% - %%

fb4C  =  
      Integrate[Sqrt[x^2 + 2  x  + 10], {x, -1, 3}]

fb5C  =  Integrate[Exp[-x^2], {x, 0, Infinity}]

Całki w których występują parametry którym nie przypisano wartości ,,symbolicznych'' (liczby całkowite, Pi, itd.)
są znacznie trudniejsze do policzenia. Tu MATHEMATICA znalazła wynik dla a>0:

fb6C = Integrate[r^3/Sqrt[a^2 - r^2], {r, 0, a}]

O to zwykle chodzi:

fb6C2  =  Assuming[a > 0, Simplify[fb6C]]

fb7  =  x^2/(x^4 + 13 x^2 + 36)

fb7C  =  Integrate[fb7, {x, 0, Infinity}]

Jak widać mamy kolejną metodę liczenia Pi:

10 NIntegrate[fb7, {x, 0, Infinity}]

fb8  =  x Sin[x]/(1 + x^2)^2

fb8C = Integrate[fb8, {x, 0, Infinity}]

Ta całka nie istnieje:

fb9  =  1/x/Log[x]

Integrate[fb9, {x, 1, 2}]

Plot[fb9, {x, 1, 2}]

W takich przypadkach należy uważać z całkowaniem numerycznym! Zwykle dostajemy zły wynik:

NIntegrate[fb9, {x, 1, 2}, MaxRecursion -> 50]

W rzeczywistości ta całka jest nieskończona!