Oblicz całki nieoznaczone.

f1a  =  1/Sqrt[x]/(1 + x^(1/3))

Do obliczenia całki nieoznaczonej używamy Integrate[funkcja, zmienna].

f1aC  =  Integrate[f1a, x]

Funkcja pierwotna f1aC powinna być ciągła. Sprawdzamy to na wykresie.

Plot[f1aC, {x, 0, 10}]

Dobrym testem na poprawność wyniku który daje Integrate jest policzenie pochodnej (D[wyrazenie,zmienna]).
MATHEMATICA zawsze liczy dobrze pochodne, wiec poniższe wyrażenie musi być równe zeru jeżeli całka została policzona dobrze.

D[f1aC, x] - f1a

Na pierwszy rzut oka wynik nie jest równy zeru. Aby uprościć wyrażenie używamy Simplify[] i jak widać otrzymujemy zero. Wszystko wskazuje na to że całka została policzona poprawnie.

Simplify[%]

Powtarzamy powyższą procedure powtarzamy dla każdej całki.

f2a  =  x/(1 + x^4)

f2aC  =  Integrate[x/(1 + x^4), x]

Plot[f2aC, {x, -10, 10}]

D[f2aC, x] - f2a

f3a  =  x^2/Cos[x^3]^2

f3aC  =  Integrate[f3a, x]

Plot[f3aC, {x, -Pi, Pi}]

Wykres pokazuje, że funkcja pierwotna nie jest ciągła. Zwykle oznacza to kłopoty: całka ma sens tylko
dla pewnych przedziałów, lub wynik jest błędny. Można to ocenić rysując wykres FUNKCJI PODCAŁKOWEJ:

Plot[f3a, {x, -Pi, Pi}]

Jak widać funkcja podcałkowa zmierza do nieskończoności w wielu punktach. Może (ale nie musi) oznaczać to że całka oznaczona nie jest zbieżna (nie istnieje):

Integrate[f3a, {x, -2, 2}]

Jeżeli jednak przedział całkowania nie zawiera punktów dla których f. zmierza do nieskończoności całkę można łatwo obliczyć:

Integrate[f3a, {x, -1, 1}]

f4a  =  1/x/Log[x]^2

f4aC  =  Integrate[f4a, x]

Warto wiedzieć jak wyłączyć te komunikaty powyżej:

Off[General::spell1]

D[f4aC, x] - f4a

f5a  =  Exp[x] Sin[2  x]

f5aC  =  Integrate[f5a, x]

Ta całka jest bardzo dobrym przykładem różnych ciekawych zagadnień. Na pierwszy rzut oka wszystko jest proste:

f6a  = (4  x^2 + 4  x - 11)/(2  x - 1)/(2  x + 
              3)/(2  x - 5)

Plot[f6a, {x, -10, 10}]

f6aC  =  Integrate[f6a, x]

D[f6aC, x] - f6a

Simplify[%]

Sprobójmy jednak zadać pare niewygodnych pytań. Np. jak wygląda całka nieoznaczona dla 2x-5<0 ?

Plot[f6aC, {x, -5, 5}]

Problem wynika z tego, że MATHEMATICA zawsze liczy całkę nieoznaczoną FUNKCJI ZESPOLONEJ, a nie
rzeczywistej. Dlatego wynik tez jest ZESPOLONY. Możemy zmusić MATHEMATICE do znalezienia funkcji pierwotnej dla x<-5/2 licząc całkę oznaczoną po osi rzeczywistej, z punktem poczatkowym w dowolnym
punkcie x<-5/2 i ze zmienną górną granicą:

f6aC2  =  
      Assuming[t ∈ Reals, Integrate[f6a, {x, -10, t}]]  /.  
        t -> x

,,Wyciągamy'' wynik całkowania  w interesującym nas przedziale -10<x<-3/2 (w rzeczywistości wynik
jest poprawny dla x<-10 ale M. tego jak widać ,,nie wie''):

f6aC3  =  
      Assuming[-10 < x < -3/2, Simplify[f6aC2]]

Jak widać wynik jest inny niż poprzedni, ale poprawny:

D[f6aC3, x] - f6a  // Simplify

Jak widać funkcje pierwotne mają inną postać analityczną:

FullSimplify[f6aC3 - f6aC]

Teraz można narysować 2 fragmenty (rzeczywistej) funcji podcałkowej:

f6w1  =  
      Plot[f6aC3, {x, -20, -3/2}, 
        DisplayFunction -> Identity]
f6w2  =  
      Plot[f6aC, {x, 5/2, 10}, DisplayFunction -> Identity]

Show[f6w1, f6w2, DisplayFunction -> $DisplayFunction]

Ciągle brakuje 2 funkcji pierwotnych dla -3/2<x<2/5

f6aC4  =  
      Assuming[t ∈ Reals, Integrate[f6a, {x, 0, t}]]  /.  
        t -> x

f6aC5  =  Assuming[0 < x < 1/2, Simplify[f6aC4]]

f6aC6  =  
      Assuming[t ∈ Reals, Integrate[f6a, {x, 1, t}]]  /.  
        t -> x

f6aC7  =  Assuming[1 < x < 5/2, Simplify[f6aC6]]

f6w3  =  
      Plot[f6aC5, {x, -3/2, 1/2}, 
        DisplayFunction -> Identity]
f6w4  =  
      Plot[f6aC7, {x, 1/2, 5/2}, 
        DisplayFunction -> Identity]

Wreszcie funkcja pierwotna dla wszystkich 4 przedziałów rzeczywistch:

Show[f6w1, f6w2, f6w3, f6w4, 
      DisplayFunction -> $DisplayFunction]

Kilka słów komentarza na temat powyższej całki:
1) całka uzyskana przez Integrate to funkcja pierwotna w sensie zespolonym i jest to jedna funkcja
2) jeżeli interesuje nas całka w sensie rzeczywistym (np. pole pod wykresem funkcji itp) to musimy obliczać całkę oznaczoną i podać dodatkowe informacje np. że górna granica całkowania jest rzeczywista.
3) tak rozumiana całka to kilka różnych wyrażeń majacych sens tylko w pewnych przedziałach

f7a  =  (Sqrt[x + 1] + 1)/((x + 1)^2 - 
            Sqrt[x + 1])

f7aC  =  Integrate[f7a, x]

D[f7aC, x] - f7a  // Simplify

f8a  = Sin[x]^2 Cos[x]^2

f8aC  =  Integrate[f8a, x]

D[f8aC, x] - f8a  // Simplify

f9a  =  1/Sin[x]/Cos[2  x]

f9aC  =  Integrate[f9a, x]

Tutaj mamy do czynienia z kolejnym przykładem całki dającej wynik w ewidentnie zespolonej postaci. Calka jest poprawna:

D[f9aC, x] - f9a  // Simplify