Needs["ccgrg`"]; (* http://library.wolfram.com/infocenter/MathSource/8848/ *)
version

x={t,r,ϑ,φ}

(*c=1*)

Sinn=(#&) (* Model płaski *)

(*Sinn=Sinh*) (* Model otwarty *)

(*Sinn=Sin*)  (* Model zamknięty *)

Definiuję sferycznie symetryczną metrykę:

g=DiagonalMatrix[{-c^2,a[t]^2,a[t]^2 ((Sinn[r])^2),a[t]^2 ((Sinn[r])^2)((Sin[ϑ])^2)}]

open[x,g]

Założenia sprowadzające się do stwierdzenia, że nigdzie nie ma horyzontu.

$Assumptions=0<ϑ<Pi&&c>=1&&Csc[r]>0&&a[t]>0

Czteroprędkość cząstki spoczywającej:

timelikeEigenvector[G‡,U]

Outer[U,-all]//Simplify

Podręcznikowy wzór na tensor energii-pędu płynu o gęstości energii ϵ[r] oraz ciśnieniu p[r]:

tTMP=Function[{i,j},(ρ[t]c^2+p[t])U[i]U[j]+p[t]g‡[i,j]]

T[i_,j_]:=tensorExt[tTMP][i,j]

Cztery równania Einsteina:

eq1=(G‡[-1,-1]-8 Pi G/c^4 T[-1,-1])+Λ g‡[-1,-1]//Simplify//Expand

eq2=(G‡[-2,-2]-8 Pi G/c^4 T[-2,-2])+Λ g‡[-2,-2]//Simplify//Expand

eq3=(G‡[-3,-3]-8 Pi G/c^4 T[-3,-3])+Λ g‡[-3,-3]//Simplify

eq4=(G‡[-4,-4]-8 Pi G/c^4 T[-4,-4])+Λ g‡[-4,-4]//Simplify

(eq1//Expand)/.{a'[t]->H[t] a[t]}

eqF=3 H[t]^2 ==(3H[t]^2/.Solve[%==0,H[t]][[1]])//Expand

eq1+3eq2 a[t]^2/c^2//Simplify

eqD=a''[t]/a[t]==Collect[(a''[t]/.Solve[%==0,a''[t]][[1]])/a[t]//Expand, G Pi ]

Układ równań opisujących dynamikę Wszechświata:

sys={eqF,eqD}

(*sys={((a''[t])/(a[t]))==(((c^2) Λ)/3)-((4 G π p[t])/(c^2))-(4/3) G π ρ[t],3 ((H[t])^2)==(c^2) Λ+8 G π ρ[t]}*)

Sprawdzenie wzorów płaskiego modelu pyłowego Λ-CDM (# oznacza czas t):

sys/.{p->(0&),a->(Sinh[Sqrt[3Λ]/2 c #]^(2/3)&),ρ->(Λ c^2/(8 Pi G)/Sinh[Sqrt[3Λ]/2 c #]^2&),H->(c Sqrt[Λ/3]/Tanh[(1/2) (Sqrt[3]) c # (Sqrt[Λ])]&)}

Simplify[%,Λ>0]

Sprawdzenie wzorów płaskiego modelu wczesnego Wszechświata (radiacyjnego):

sys/.{p->(c^2/(32 Pi G #^2)&),a->(Sqrt[2#]&),ρ->(3/(32 Pi G #^2)&),H->(1/2/#&)}

Simplify[%]

Sprawdzenie wzorów płaskiego modelu pyłowego bez Λ:

sys/.{p->(0&),a->(#^(2/3)&),ρ->(1/(6 Pi G #^2)&),H->(2/3/#&)}

Simplify[%]