A&A Wykład 2

Równowaga hydrostatyczna 
i samograwitacja

Dynamic[{DateString[],Clock[{1,1},1]}//First]

Andrzej Odrzywołek

Zakład Teorii Względności i Astrofizyki, Instytut Fizyki Teoretycznej UJ

Sferyczna symetria

Praktyka pokazuje, że w astrofizyce z obliczeniami, które nie zakładają
symetrii sferycznej spotykamy się niezwykle rzadko! Ot co będziemy rozważać :

Droga do modelu Ziemi

Celem kilku następnych wykładów jest stworzenie serii sensownych
i coraz dokładniejszych modeli Ziemi

Ziemię traktujemy jako prototpowe ciała niebieskiego

Ziemia jest w przybliżeniu sferycznie symetryczna i stabilna

Równowaga hydrostatyczna: w jaki sposób Ziemia utrzymuje niemal statyczny rozkład gęstości i ciśnienia?

Dlaczego jest kulista?

Równanie stanu (EOS): jaka jest zależność ciśnienia od gęstości; dalej także temperatury i składu chemicznego?

Lista obiektów sferycznie symetrycznych w astrofizyce

Obiekty, dla których założenie o sferycznej symetrii jest uzasadnione:

planety, planety karłowate, duże księżyce,

większość gwiazd

gwiazdy neutronowe, białe karły, czarne dziury

gromady kuliste gwiazd

gromady galaktyk

Wszechświat

Obiekty, dla których założenie o sferycznej symetrii jest nieuzasadnione:

galaktyki spiralne

dyski akrecyjne

obiekty bardzo szybko rotujące

ciasne układy podwójne

Równania równowagi hydrostatycznej

D[P[r],r]==-g[r]ρ[r] (* Równanie na gradient ciśnienia *)

g[r]==G m[r]/r^2 (* Wzór na natężenie pola grawitayjnego w symetrii sferycznej *)

Mamy na razie 2 równania (pierwsze różniczkowe, drugie algebraiczne) na 4 niewiadome funkcje:
1. P[r] - zależność ciśnienia P od promienia (odległości od centrum) r
2. g[r] - zależność natężenia pola grawitacyjnego (“przypieszenia ziemskiego’’) g od r
3. ρ[r] - zależność gęstości materii ρ od r
4. m[r] - masa m zawarta wewnątrz kuli o promieniu r
Potrzebujemy jeszcze 2 równań!

m[r]==Integrate[ρ[rr] 4 π rr^2,{rr,0,r}]

D[%,r]

Powyższe często nazywamy równaniem ciągłości. Nadal brakuje jednego równania!

Barotropowe równanie stanu

Aby domknąć układ równań równowagi hydrostatycznej, potrzebujemy termodynamicznego związku pomiędzy ciśnieniem i gęstością. W najprostszym przypadku ignorujemy wszystkie inne wielkości termodynamiczne (w szczególności: temperaturę T, skład chemiczny (Subscript[X, i]), przemiany fazowe, potencjał chemiczny μ). Równanie stanu (ang. Equation Of State, EOS) ma postać:

P[ρ_]:=f[ρ]

gdzie f jest pewną funkcją. Dla ilustracji przyjmiemy, że:

P[ρ_]:=K ρ

W chwili optymizmu spróbujemy rozwiązać układ równań rónowagi hydrostatycznej za pomocą DSolve

ukladRownan={D[P[ρ[r]],r]==- G m[r]ρ[r]/r^2,m'[r]==4 π r^2 ρ[r]}

DSolve[ukladRownan,{ρ,m},r]

Niestety, nie udało się....

Warunki początkowe i brzegowe dla układu równań równowagi hydrostatycznej

Aby podjąć próbę numerycznego rozwiązania za pomocą NDSolve musimy podać warunki początkowe lub/i brzegowe. Najprościej zadać je w centrum:

warunkiPoczatkowe = {m[0]==0,ρ[0]==ρC}

Pierwszy warunek jest oczywisty: masa kuli o promieniu zero; drugi zadaje gęstość w centrum i ,,numeruje’’ różne obiekty zbudowane z materii o identycznym równaniu stanu, np: coraz  większe.

NDSolve[Join[ukladRownan,warunkiPoczatkowe],{ρ,m},{r,0,1}]

Aby użyć NDSolve WSZYSTKIE symbole literowe muszą mieć nadane jakieś wartości. Dla przykładu ustawiamy je na 1.

Block[{G=1,ρC=1,K=1},NDSolve[Join[ukladRownan,warunkiPoczatkowe],{ρ,m},{r,0,1}]]

Kolejny problem: dzielenie przez zero. Rozwiązywanie musimy rozpocząć w pewnej odległości or r=0. Na razie po prostu wstawimy r=ϵ, gdzie ϵ to jakaś bardzo mała (z punktu wiczenia komputera) liczba. Skorzystamy z faktu, że kula o promieniu ϵ ma masę m=4/3 π (ϵ^3)ρC.

ϵ=Sqrt[$MachineEpsilon]

$MachineEpsilon//Log2

warunkiPoczatkowe={m[ϵ]==4/3 π ϵ^3 ρC,ρ[ϵ]==ρC}

rozw=Block[{G=1,ρC=1,K=1},NDSolve[Join[ukladRownan,warunkiPoczatkowe],{ρ,m},{r,0,11}]]

{dens,mass}={ρ,m}/.rozw[[1]]

Plot[dens[r],{r,0,5},PlotRange->{0,1},PlotStyle->Black]

Podsumowanie problemu r. hydrostatycznej

Równanie na gradient ciśnienia + związek grawitacji z masą

Równanie ciągłości (zachowanie masy)

Równanie stanu EOS: P = f[ρ]

Warunki początkowe: {m[0]==0,ρ[0]==ρC}

Osobliwość usuwalna w r=0

W typowch sytuacjach rozwiązanie istnieje i jest jednoznaczne, i jako takie może zostać wyznaczone numerycznie.

Entalpia i algebraiczne równanie równowagi

Wprowadzając entalpię właściwą h=H/V/ρ

Quit[]

h=Integrate[D[P[ρ[r]],ρ[r]]/ρ[r],r]

możemy lewą stronę równania na gradient ciśnienia zapisać jako pochodną

D[h,r]

Podobnie, prawą stronę (g) możemy zapisać jako gradient potencjału grawitacyjnego (Subscript[Φ, g])

g=D[Φg[r],r]

D[h,r]+g

Oznacza to, że równanie sprowadza się do algebraicznego związku:

Clear[h]

h+Φg==C

Różniczkowa i całkowa wersja równania równowagi

Stosując operator Laplace’a we współrzędnych sferycznych do entalpii właściwej

Laplacian[h[r],{r,θ,φ},"Spherical"]

oraz używając równania Poissona (Subscript[ΔΦ, g])=4 π G ρ, otrzymujemy równanie różniczkowe:

((2 h'[r])/r)+h''[r] + 4 π G ρ[r]==0

Analogicznie, używając całkowego wzoru na (Subscript[Φ, g])=- G ∫ρ[r’]/|r-r’| dV otrzymamy postać całkową.