Celem poniższych rachunków jest zbadanie stabilności punktów Lagrange’a. Z analizy potencjału U(X,Y) wiemy, że (Subscript[L, 123]) to punkty siodłowe, natomiast (Subscript[L, 45]) to maksimum U. Jak wygląda ruch w otoczeniu punktów Lagrange’a?

sysROT2={-(Ω^2) X[t]-((d G m M)/((m+M) (((((((d M-(m+M) X[t]))^2)/(((m+M))^2))+((Y[t])^2)))^(3/2))))+((G m X[t])/(((((((d M-(m+M) X[t]))^2)/(((m+M))^2))+((Y[t])^2)))^(3/2)))+((d G m M)/((m+M) (((((((d m+(m+M) X[t]))^2)/(((m+M))^2))+((Y[t])^2)))^(3/2))))+((G M X[t])/(((((((d m+(m+M) X[t]))^2)/(((m+M))^2))+((Y[t])^2)))^(3/2)))-2 Ω Y'[t]+X''[t],-(Ω^2) Y[t]+((G m Y[t])/(((((((d M-(m+M) X[t]))^2)/(((m+M))^2))+((Y[t])^2)))^(3/2)))+((G M Y[t])/(((((((d m+(m+M) X[t]))^2)/(((m+M))^2))+((Y[t])^2)))^(3/2)))+2 Ω X'[t]+Y''[t]};

Na tapetę bierzemy punkt (Subscript[L, 5]).

sysROT2/.{X->(d(M-m)/(M+m)/2&), Y->(d Sqrt[3]/2&),Ω->Sqrt[G(m+M)/d^3]}

Współrzędne punktu (Subscript[L, 5]) spełniają oczywiście równania ruchu.

Simplify[%,d>0]

Zgodnie z zasadami rachunku zaburzeń, do wsp. punktu (Subscript[L, 5]) dodajemy małe zaburzenie x,y (uwaga na kolizję oznaczeń z ukł. inercjalnym xy!) pomnożone w celach rachunkowych przez ,,mały’’ parametr perturbacyjny ϵ.

sysROT2/.{X->(d(M-m)/(M+m)/2+ϵ x[#]&), Y->(d Sqrt[3]/2 + ϵ y[#]&),Ω->Sqrt[G(m+M)/d^3]}

Simplify[%,d>0]

Series[%,{ϵ,0,1}]//Normal

Simplify[%,d>0]

D[%,ϵ]

Expand[%]

sysLINEAR=%

sysLINEAR/.G->Ω^2 d^3/(m+M)

sysLINEAR2=FullSimplify[%,d>0]/.(Sqrt[(Ω^2)])->Ω

Mathematica potrafi oczywiście rozwiązać układ liniowy, ale wynik nie jest klarowny.

DSolve[sysLINEAR2=={0,0},{x,y},t]

Podejdziemy do problemu podręcznikowo.

sysLINEAR2/.m->q M//FullSimplify

%/.{x->(A Exp[λ #]&),y->(B Exp[λ #]&)}

Collect[%,Exp[t λ]]

%/Exp[t λ]

eqns=%;

vars={A,B};

macierz=Table[D[eqns[[i]],vars[[k]]],{i,1,2},{k,1,2}]//Simplify

macierz//MatrixForm

Det[macierz]

%/.Ω->Sqrt[G(m+M)/d^3]//Simplify

FullSimplify[%/.m->q M]

eigeneq=Expand[%]

Clear[G,M,d]

Exists[λ,Re[λ]>0&&λ∈Complexes,eigeneq==0&&m>0&&M>0&&d>0&&G>0]

Wiedząc, że wynik zależy tylko od stosunku mas q=m/M, obliczenia można przyspieszyć.

G=1

d=1

M=1

Exists[λ,Re[λ]>0&&λ∈Complexes,eigeneq==0&&q>0]

Resolve[%]

N[%]