Skala czasowa dynamiczna

GM=1;R=1;

DSolve[{r''[t]==-GM/r[t]^2,r[0]==R,r'[0]==0},r,t]

rozw=DSolve[{r'[t]^2/2==GM/r[t]-GM/R,r[0]==R},r,t] (* Skoro rozw. równań Newtona nie zadziałało, stosujemy zasadę zachownaia energii *)

r[0]/.rozw

Solve[(r[T]/.rozw[[1]])==0,T]

τ0=T/.%[[1]]

(* Dla GM=R=1 jednostką czasu jest 1/Sqrt[GM/(R^3)]. Przywracamy jednostki i wprowadzamy gęstość średnią. *)

Clear[GM,R]

τ0/Sqrt[G M/R^3]/.M->4/3Pi R^3ρ//(#^2&) (* Słynny wzór na (τ^(2 ))*)

τ=Sqrt[%] (* Mathematica formatuje go po swojemu...nieważne, liczy się 1/Sqrt[Gρ]. *)

Sqrt[3/(32 Pi)]/Sqrt[Quantity[1,"GravitationalConstant"]Quantity[1,"EarthMass"]/(4/3 Pi Quantity[1,"EarthAuthalicRadius"]^3)]

UnitConvert[%] (* Czas dla Ziemi *)

Sqrt[3/(32 Pi)]/Sqrt[Quantity[1,"GravitationalConstant"]Quantity[1,"SolarMass"]/(4/3 Pi Quantity[1,"SolarRadius"]^3)]

UnitConvert[%] (* Czas dla Słońca *)

Sqrt[3/(32 Pi)]/Sqrt[Quantity[1,"GravitationalConstant"]Quantity[1.45,"SolarMass"]/(4/3 Pi Quantity[2000,"km"]^3)]//UnitConvert (* Czas kolapsu zdegenerowanego jądra supernowej *)

UnitConvert[ Sqrt[3/(32 Pi)]/Sqrt[Quantity[1,"GravitationalConstant"]Quantity[1,"UniverseDensity"]],"Years"] (* Czas kolapsu Wszechświata *)