// This is a Singular file that shows that there is no such solutions of the
// Ernst-Maxwell equations that 

// \varphi=O(|z-z0|^2) with non-zero Hessian at z0 and E=O(|z-z0|^9)

timer=1;

option(prot);

int tt = timer;

int k=5;

int n=2;

ring R = 0,(c(4..27),d(4..27),rho0,w,z),dp;

// Taylor expansion of \varphi

poly va;

va=z2+c(4)*zw+c(5)*w2+c(6)*z3+c(7)*z2w+c(8)*zw2+c(9)*w3+c(10)*z4+c(11)*z3w+c(12)*z2w2+c(13)*zw3+c(14)*w4+c(15)*z5+c(16)*z4w+c(17)*z3w2+c(18)*z2w3+c(19)*zw4+c(20)*w5+c(21)*z6+c(22)*z5w+c(23)*z4w2+c(24)*z3w3+c(25)*z2w4+c(26)*zw5+c(27)*w6;

poly vb;

vb=w2+d(4)*wz+d(5)*z2+d(6)*w3+d(7)*w2z+d(8)*wz2+d(9)*z3+d(10)*w4+d(11)*w3z+d(12)*w2z2+d(13)*wz3+d(14)*z4+d(15)*w5+d(16)*w4z+d(17)*w3z2+d(18)*w2z3+d(19)*wz4+d(20)*z5+d(21)*w6+d(22)*w5z+d(23)*w4z2+d(24)*w3z3+d(25)*w2z4+d(26)*wz5+d(27)*z6;

// Ernst-Maxwell equation 
// (only the second equation is nontrivial in this order)

poly EM2  = (2*(2*rho0+z+w))^2*(va*diff(diff(va,z),w)-2*diff(va,w)*diff(va,z))+(2*(2*rho0+z+w))*va*(diff(va,z)+diff(va,w))-va^2; 

poly EM2c = (2*(2*rho0+z+w))^2*(vb*diff(diff(vb,w),z)-2*diff(vb,z)*diff(vb,w))+(2*(2*rho0+z+w))*vb*(diff(vb,w)+diff(vb,z))-vb^2;

intvec v=0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1,1;

EM2=jet(EM2,n+4,v);
EM2c=jet(EM2c,n+4,v);

matrix C2 = coef(EM2,zw);

matrix C2c = coef(EM2c,zw);

ideal C;

ideal Co = C2[2,1..25];

C= ideal(Co);

Co = C2c[2,1..25];

C=C + ideal(Co);

 ring R2 = 0,(c(4..27),d(4..27),rho0),dp;

 ideal C = imap(R,C);

"-----------------C-----------------------";
C;

// ideal gC = groebner(C);

// "dimension:",dim(gC);

//size(gC);

//gC;

 LIB "primdec.lib";

 list mpr = minAssGTZ(C); 

"";
"used time:",timer-tt, "sec";
"used memory:", memory(2) / (1024*1024), "MB";
""; 

// 0=1, hence there are no solutions!

mpr;

"test C:";

int l;
int i;
for (i=1; i<=size(mpr); i++)
{
l= l+size(reduce(C,std(mpr[i])));
}
l;